Portal | IBM Manuals | Downloads | Products | Refer | Info | Programs | JCLs | Forum Rules | Buy Our Software DVD 
IBMMAINFRAMES.com - IBM Mainframe Support Forums Index
 
Register
 
IBMMAINFRAMES.com - IBM Mainframe Support Forums Index FAQ Search Memberlist Usergroups Profile Log in to check your private messages Log in
 
foggy sentence generator

 
Post new topic   Reply to topic    IBMMAINFRAMES.com Support Forums -> General Talk & Fun Stuff
Author Message
enrico-sorichetti

Senior Member


Joined: 14 Mar 2007
Posts: 9676
Location: italy

PostPosted: Mon Oct 27, 2008 12:31 am    Post subject: foggy sentence generator
Reply with quote

to those interested
while testing I got some realistic managerspeak sentences icon_biggrin.gif

for mvs just store it with any name ( foggy for example ) somewhere in Your SYSPROC/SYSEXEC concatenation

if Your pc/workstation has object_rexx regina_rexx bRexx installed
just follow the rules

for mac os x, and unix/linux like
just add/modify the shebang line with the proper rexx interpreter location
( take away the shebang line for mvs )

and remember....
Quote:
In theory, the product assurance architecture adds explicit
performance limits to any discrete configuration mode.

Code:

#! /opt/ooRexx/bin/rexx
Parse Arg times
/* List of LEADINS, all of which mean nothing but buy time */
leadin.1  = "In particular,"
leadin.2  = "On the other hand,"
leadin.3  = "However,"
leadin.4  = "Similarly,"
leadin.5  = "As a resultant implication,"
leadin.6  = "In this regard,"
leadin.7  = "Based on integral subsystem considerations,"
leadin.8  = "For example,"
leadin.9  = "Thus,"
leadin.10 = "In respect to specific goals,"
leadin.11 = "Interestingly enough,"
leadin.12 = "Without going into the technical details,"
leadin.13 = "Of course,"
leadin.14 = "To approach true user-friendliness,"
leadin.15 = "In theory,"
leadin.16 = "It is assumed that"
leadin.17 = "Conversely,"
leadin.18 = "We can see, in retrospect,"
leadin.19 = "It is further assumed that"
leadin.20 = "Further,"
leadin.21 = "In summary,"
leadin.22 = "It should be noted that"
leadin.23 = "To further describe and annotate,"
leadin.24 = "Specifically,"
leadin.0  = 24

/* List of SUBJECT clauses chosen for no redeeming value whatsoever */
subject.1  = "a large portion of interface coordination communication"
subject.2  = "a constant flow of effective communication"
subject.3  = "the characterization of specific criteria"
subject.4  = "initiation of critical subsystem development"
subject.5  = "the fully integrated test program"
subject.6  = "the product configuration baseline"
subject.7  = "any associated supporting element"
subject.8  = "the incorporation of additional mission constraints"
subject.9  = "the independent functional principle"
subject.10 = "the interrelation of system and/or subsystem technologies"
subject.11 = "the product assurance architecture"
subject.0  = 11

/* List of VERB clauses chosen for auto-recursive obfuscation */
verb.1  = "must utilize and be functionally interwoven with"
verb.2  = "maximizes the probability of project success, yet minimizes cost and time required for"
verb.3  = "adds explicit performance limits to"
verb.4  = "necessitates that urgent consideration be applied to"
verb.5  = "requires considerable systems analysis and trade-off studies to arrive at"
verb.6  = "is further compounded when taking into account"
verb.7  = "presents extremely interesting challenges to"
verb.8  = "recognizes other systems' importance and the necessity for"
verb.9  = "affects a significant implementation of"
verb.10 = "adds overriding performance constraints to"
verb.11 = "mandates staff-meeting-level attention to"
verb.12 = "is functionally equivalent and parallel to"
verb.0  = 12

/* List of OBJECT clauses selected for profound meaninglessness */
object.1  = "the most recent level of hardware.  "
object.2  = "the anticipated fourth-generation equipment.  "
object.3  = "the subsystem compatibility testing.  "
object.4  = "the structural design, based on system engineering concepts.  "
object.5  = "the preliminary qualification limit.  "
object.6  = "the evolution of specifications over a given time period.  "
object.7  = "the philosophy of commonality and standardization.  "
object.8  = "the greater fight-worthiness concept.  "
object.9  = "any discrete configuration mode.  "
object.10 = "the management-by-contention principle.  "
object.11 = "the total system rationale.  "
object.12 = "possible bidirectional logical relationship approaches.  "
object.13 = "the postulated use of dialog management technology.  "
object.14 = "the overall negative profitability.  "
object.0  = 14

If times = '?' Then Do
    say   "foggy.rex"
    say   " FOGGY is an interactive productivity tool designed to assist"
    say   " in the composition of monthly reports, project plans, memos to"
    say   " management and so forth.  If entered without parameters,"
    say   " FOGGY generates as output a high-fog-index sentence suitable for"
    say   " befuddling even the most determined seeker-after-content.  If you"
    say   " need vast amounts of FOGGY for really serious tush-covering, enter"
    say   " the number of sentences needed as a parameter.  For example,"
    say   " entering 'FOGGY 5' outputs half a screen of heat-treated, battle-"
    say   " hard, industrial-strength slop, well suited to choking hogs and"
    say   " assurance planners. "
    say   ""
    say   " REMEMBER:"
    say   " FOGGY can be a terrible weapon -- never abuse it."
    Exit
End

If times = '' Then times = 1

leadnum  = 0
subnum   = 0
verbnum  = 0
objnum   = 0
lastlead = leadnum
lastsub  = subnum
lastverb = verbnum
lastobj  = objnum
outstuff = ''
linesize = 64

/* And, last but not least, here's the program */
Do i = 1 To times
  Do While leadnum = lastlead
    leadnum = RANDOM(1, leadin.0)
  End

  Do While subnum = lastsub
    subnum = RANDOM(1, subject.0)
  End

  Do While verbnum = lastverb
    verbnum = RANDOM(1, verb.0)
  End

  Do While objnum = lastobj
    objnum = Random(1, object.0)
  End

  outstuff = outstuff leadin.leadnum subject.subnum verb.verbnum object.objnum

  lastlead = leadnum;
  lastsub  = subnum;
  lastverb = verbnum;
  lastobj  = objnum;

End /* do */

/* OK, now lets put that data out NICELY */
Do Until outstuff = ''
  k = Lastpos(' ',outstuff,Min(linesize,Length(outstuff)))
  Say  Strip(Left(outstuff,k))
  outstuff = Strip(Substr(outstuff,k+1),'L')
End

Back to top
View user's profile Send private message

dick scherrer

Global Moderator


Joined: 23 Nov 2006
Posts: 19296
Location: 221 B Baker St

PostPosted: Mon Oct 27, 2008 1:42 am    Post subject: Reply to: foggy sentence generator
Reply with quote

Heh heh heh. . .

d
Back to top
View user's profile Send private message
Display posts from previous:   
Post new topic   Reply to topic    IBMMAINFRAMES.com Support Forums -> General Talk & Fun Stuff All times are GMT + 6 Hours
Page 1 of 1

 



 
Master the Mainframes | Bookmarks | Subscriptions | Site Map | Polls | Photos | FAQ | Rules | Contact Us